# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

DESCRIPTION="Reimplementation of the Infinity engine"
HOMEPAGE="http://gemrb.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"

DEPEND=">=media-libs/libsdl-1.2
	media-libs/openal
	>=dev-lang/python-2.3"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/fix_endian.patch" # r4807 upstream
	sed -i 's|\$(bindir)/plugins/|\$(libdir)/|' \
		Makefile.am || die "move plugindir failed"
	sed -i 's|\$(bindir)/Cache|var/cache/gemrb|' \
		Makefile.am || die "move cache failed"
	sed -i '/NullSound/d' \
		gemrb/plugins/Makefile.am || die "enable sound failed"
	sed -i '/sysconf_DATA = GemRB.cfg.sample/d' \
		gemrb/Makefile.am || die "remove default config failed"
	if ! use doc ; then
		sed -i 's|^SUBDIRS = \(.*\) docs|SUBDIRS = \1|' \
		gemrb/Makefile.am || die "don't install docs failed"
	fi
}

src_compile() {
	eautoreconf || die "eautoreconf failed"
	egamesconf \
		--docdir="/usr/share/doc/${PF}" \
		|| die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	libtool --finish "${GAMES_LIBDIR}"
	chgrp ${GAMES_GROUP} "${D}/var/cache/gemrb"
	chmod g+w "${D}/var/cache/gemrb/"
	prepgamesdirs
	dodoc "${FILESDIR}/GemRB.cfg.sample"
	dodoc README AUTHORS
	prepalldocs
}